Test Statistics for Popular Significance Tests
One sample test of a mean
Assuming a sample of data in range x, drawn from a population with mean $$\mu$$ and standard deviation $$\sigma$$:
| H0: $$\mu=\mu_0$$ H1: $$\mu \neq \mu_0$$ | |||
| Test statistic, z | =(AVERAGE(x)-mu0)/(sigma/SQRT(COUNT(x))) | assuming $$\sigma$$ known | |
| Test statistic, t | =(AVERAGE(x)-mu0)/(STDEV(x)/SQRT(COUNT(x))) | assuming $$\sigma$$ unknown | |
One sample test of a variance
Assuming a sample of data in range x, drawn from a population with mean $$\mu$$ and standard deviation $$\sigma$$:
| H0: $$\sigma^2=\sigma_0^2$$ H1: $$\sigma^2 > \sigma_0^2$$ | |||
| Test statistic, $$\chi^2$$ | =DEVSQ(x)/sigma0^2 | ||
Two sample test of difference between means
Assuming two samples of data in ranges x and y, drawn from populations with means $$\mu_1$$ and $$\mu_2$$ and equal variances:
| H0: $$\mu_1 - \mu_2 = c$$ H1: $$\mu_1 - \mu_2 \ne c$$ | |
| Estimate the unknown common standard deviation by the pooled estimate: | |
| s | =SQRT((DEVSQ(x)+DEVSQ(y))/(COUNT(x)+COUNT(y)-2)) |
| Test statistic, t | =(AVERAGE(x)-AVERAGE(y)-c)/(s*SQRT(1/COUNT(x)+1/COUNT(y))) |
Two sample test of ratio of variances
Assuming two samples of data in ranges x and y, drawn from populations with variances $$\sigma_1^2$$ and $$\sigma_2^2$$:
| H0: $$\sigma_1^2 = \sigma_2^2$$ H1: $$\sigma_1^2 > \sigma_2^2$$ | |
| Test statistic, F | =VAR(x)/VAR(y) |
Chi-squared test of association
Assuming a two-way contingency table of observed frequencies.
| H0: | row factor independent of column factor |
| H1: | some association between row and column factors |
The suggested layout below for a 4x2 table can easily be modified for tables of other sizes.
| A1: | =SUM(C3:D6) | |
| A3: | =SUM(C3:D3) | copy down to A6 |
| C1: | =SUM(C3:C6) | copy across to D1 |
| G3: | =$A3*C$1/$A$1 | copy into G3:H6 |
| C8: | =CHITEST(C3:D6,G3:H6) | |
| C9: | =(COUNT(A3:A6)-1)*(COUNT(C1:D1)-1) | |
| C10: | =CHIINV(C8,C9) |